//=============================================================================
// JumpMod
//
// This mutator allows a server to configure the abilities for players to jump
// around as well as how much boost they receive with each jump.
//
// Contact : bob.chatman@gmail.com
// Website : www.gneu.org
// License : Content is available under Creative Commons Attribution-ShareAlike 
//			 3.0 License.
//=============================================================================

Class Info_JumpMod Extends ReplicationInfo DependsOn(JumpMod);

`include( JumpMod/Classes/LibraryMessage.uci )

var repnotify int riMaxNumJumps;
var repnotify int riMaxJumpBoost;                           
var repnotify UTPawn rPlayerPawn;

Replication
{
    if(bNetDirty && (Role == ROLE_Authority))
    	riMaxNumJumps, riMaxJumpBoost, rPlayerPawn;
}

simulated event ReplicatedEvent(name VarName)
{
	if (rPlayerPawn != None)
	{
		`DebugMessage("Values have been updated: rPlayerPawn" @ rPlayerPawn @ "riMaxNumJumps" @ riMaxNumJumps @ "riMaxJumpBoost" @ riMaxJumpBoost);
		rPlayerPawn.MaxMultiJump = riMaxNumJumps;
		rPlayerPawn.MultiJumpBoost = (riMaxJumpBoost * 40);
		rPlayerPawn.MultiJumpRemaining = riMaxNumJumps;
    }

	Super.ReplicatedEvent(VarName);
}

defaultproperties
{
	RemoteRole = ROLE_SimulatedProxy
	bAlwaysRelevant = True
	bOnlyRelevantToOwner = True
}