//=============================================================================
// JumpMod
//
// This mutator allows a server to configure the abilities for players to jump
// around as well as how much boost they receive with each jump.
//
// Contact : bob.chatman@gmail.com
// Website : www.gneu.org
// License : Content is available under Creative Commons Attribution-ShareAlike 
//			 3.0 License.
//=============================================================================

class UTUIFrontEnd_JumpMod extends UTUIFrontEnd	DependsOn( JumpMod );

`include( JumpMod/Classes/LibraryMessage.uci )

var transient UTUISlider  uiMaxNumJumps;
var transient UTUISlider  uiMaxJumpBoost;

event SceneActivated( bool bInitialActivation )
{
	Super.SceneActivated( bInitialActivation );

	if ( bInitialActivation )
	{
		`DebugMessage("Initializing UIFrontend information.");
		uiMaxNumJumps  = UTUISlider ( FindChild( 'sliJumps', true ) );
		uiMaxJumpBoost = UTUISlider ( FindChild( 'sliBoost', true ) );

		uiMaxNumJumps.SliderValue.CurrentValue 		= class'JumpMod.JumpMod'.default.iMaxNumJumps;
		uiMaxNumJumps.SliderValue.MinValue   		= 0;
		uiMaxNumJumps.SliderValue.MaxValue   		= 30;
		uiMaxNumJumps.SliderValue.NudgeValue 		= 1;
		uiMaxNumJumps.SliderValue.bIntRange 		= true;
		uiMaxNumJumps.UpdateCaption();

		uiMaxJumpBoost.SliderValue.CurrentValue 	= class'JumpMod.JumpMod'.default.iMaxJumpBoost;
		uiMaxJumpBoost.SliderValue.MaxValue   		= 1;
		uiMaxJumpBoost.SliderValue.MaxValue   		= 10;
		uiMaxJumpBoost.SliderValue.NudgeValue 		= 1;
		uiMaxJumpBoost.SliderValue.bIntRange 		= true;
		uiMaxJumpBoost.UpdateCaption();
	}
}                                                                                            

/** Adds on back and accept to button bar */
function SetupButtonBar()
{
	`DebugMessage("Adding Back & Accept to Button Bar");

	ButtonBar.Clear();
	ButtonBar.AppendButton( "<Strings:UTGameUI.ButtonCallouts.Back>", OnButtonBar_Back );
	ButtonBar.AppendButton( "<Strings:UTGameUI.ButtonCallouts.Accept>", OnButtonBar_Accept );
}

function bool OnButtonBar_Accept( UIScreenObject InButton, int InPlayerIndex )
{
	`DebugMessage("Saving Configuration Settings");

	class'JumpMod.JumpMod'.default.iMaxNumJumps  = uiMaxNumJumps.GetValue();
	class'JumpMod.JumpMod'.default.iMaxJumpBoost = uiMaxJumpBoost.GetValue();
	class'JumpMod.JumpMod'.static.StaticSaveConfig();

	CloseScene( self );

	return true;
}

function bool OnButtonBar_Back( UIScreenObject InButton, int InPlayerIndex )
{
	`DebugMessage("Canceling Changes");
	CloseScene( self );

	return true;
}